!
!  MC simulation of hard rods
!

implicit none
integer :: N, na, k, i, j, MCS, q, S_equil, j1
real (8) :: l, caja, phi, dx, xt, xx, eta, h
real (8), dimension(100) :: x
real (8), dimension(200) :: his

!
!  Read in simulation parameters 
!
open (100, file = 'hard_rods_MC.par')
read (100, *) N    ! number of rods
read (100, *) MCS  ! number of equilibrium MC steps
read (100, *) S_equil  ! MC steps for equilibration
read (100, *) eta  ! mean packing fraction
read (100, *) dx   ! amplitude of MC move
close (100)

l = (1-eta)/eta

open (200, file = 'hard_rods_MC.dat')

his = 0; na = 0

!
!  Initial rod configuration
!
do i = 1, N
   x(i) = 0.5d0 + (i - 1)*(l + 1d0)
end do

!
! Box length and packing fraction
!
caja = N*(l + 1d0)
phi = N/caja 
h = (caja-1)/200 ! bin for histogram

write (200, '(''N   :'', i3)') N
write (200, '(''MCS total :'', i8)') MCS
write (200, '(''MCS equil :'', i8)') S_equil
write (200, '(''dx  : '', f6.3)') dx
write (200, '(''eta : '', f6.3)') phi
write (200, '(''Box : '', f6.3)') caja

!
!  Monte Carlo steps
!
do k = 1, S_equil + MCS
   do i = 1, N ! visit all rods in sequence
      xt = x(i) + dx*(2*rand() - 1)
      do j = -1, 1, 2
         j1 = i + j
         if (j1 <= N .and. j1 >= 1) then
             if (abs(xt - x(j1)) < 1d0) go to 1
         end if
      end do
      if (xt < 0.5d0 .or. xt > caja - 0.5d0) go to 1
      x(i) = xt
      if (k > S_equil) na = na + 1
1  end do

!
!  density histogram 
!
   if (k > S_equil) then
       do i = 1, N
          q = (x(i)-0.5d0)/h + 1
          his(q) = his(q) + 1
       end do
   end if
end do

write (200, '(''Acceptance ratio: '',f6.1)') 100d0*na/(N*dble(MCS))

!
!  Final configuration
!
open (102, file = 'hard_rods_MC.out')
do i = 1, N
   write(102, *) x(i)
end do
close (102)

!
!  Write density histogram
!
open (101, file = 'hard_rods_MC.prof')
do i = 1, 200
   xx = 0.5d0 + (i-0.5d0)*h
   write(101,*) xx, his(i)/(h*MCS)
end do
close (101)

close (200)

end

